commands = {
	n,s,e,w,ne,nw,ring,a,b,c,d,take,drop
}

object knife { }
object photobook { }
object crank { }
object mice { }
object box { }
object miceInBox { }
object flask { }

stuff = {knife,photobook,crank,box,miceInBox,flask}
places = {	westshanbar,
		wsFacingRiver,
		wsTownHallOutside,
		wsSchoolOutside,
		wsHardwareStoreOutside,
		wsHardwareStoreInside,
		wsOldMillOutside,
		wsOldMillInside,
		wsGiftShopOutside
	}

room you{
	counter{shotsHad 0 3}
}

room westshanbar{
	enter{
		"You arrive in the main street of West Shanbar.";
	}
	(you,look){
		"You can turn around (South)";
		"You can go to the school (East)";
		"You can go to the town hall (West)";
		"You can go to the Gift Shop (NorthWest)";
	}
	(you,s){
		move you from westshanbar to wsFacingRiver;
	}
	(you,w){
		move you from westshanbar to wsTownHallOutside;
	}
	(you,e){
		move you from westshanbar to wsSchoolOutside;
	}
	(you,ne){
		move you from westshanbar to wsHardwareStoreOutside;
	}
	(you,nw){
		move you from westshanbar to wsGiftShopOutside;
	}
}

room wsHardwareStoreOutside{
	enter{
		"You are now in front of the Hardware store";
		"It has been abandoned for a while now";
	}
	(you,look){
		"The door is locked, but one of the walls has been destroyed";
		"You can enter from the back (North)";
	}
	(you,n){
		move you from wsHardwareStoreOutside to wsHardwareStoreInside;
	}
}

room wsHardwareStoreInside{
	enter{
		"You are now inside the Hardware store";
	}
	(you,look){
		"You see the followings things lying about";
		if(wsHardwareStoreInside contains crank){
			"A crank";
		}
		if(wsHardwareStoreInside contains box){
			"A box";
		}
		if(wsHardwareStoreInside contains mice){
			"Some mice";
			if(wsHardwareStoreInside contains box){
				"You can put the mice in the box (store mice)";
			}
		}
		if(wsHardwareStoreInside contains miceInBox){
			"A box containing the mice";
		}
		"You can go back outside (South)";
	}
	(you,take,mice){
		"You try to take the mice";
		"They jump on you and bite you until you die";
		+game.lose;
	}
	(you,store,mice){
		"You put the mice in the box";
		move miceInBox from offscreen to wsHardwareStoreInside;
		move mice from wsHardwareStoreInside to offscreen;
		move box from wsHardwareStoreInside to offscreen;
	}
	(you,s){
		move you from wsHardwareStoreInside to wsHardwareStoreOutside;
	}
}

room wsGiftShopOutside{
	enter{
		"You are outside the gift shop";
		"The door is locked, and no one seems to be there";
		"You can go back (South)";
	}
	(you,s){
		move you from wsGiftShopOutside to westshanbar;
	}
}

room wsSchoolOutside{
	enter{
		"You are now in front of the school";
	}
	(you,look){
		"The school is pretty ugly";
		"There is a bell, but only the outer shell remains";
		"Maybe you can ring it with something hard";
	}
	(you,ring){
		if(wsMsPeepersQuiz.entered){
			"Ms.Peepers: You already took the Quiz, go away.";
		}
		else{
			"You try to ring the bell";
			
			if(you contains knife){
				"You ring the bell using your knife.";
				move you from wsSchoolOutside to wsMsPeepersQuiz;
			}
			else{
				"The sound produced is inaudible";
				"You'll need the knife to ring the bell loud enough";
			}		
		}
	}
	(you,s){
		move you from wsSchoolOutside to westshanbar;
	}
}

room wsMsPeepersQuiz{
	state{entered}
	enter{
		+wsMsPeepersQuiz.entered;
		"Ms.Peepers answers the door...";
		"Ms.Peepers: Oh, hello!";
		"Ms.Peepers: Answer this question";
		" ";
		"When was this game released?";
		"a) 1993";
		"b) 1996";
		"c) 1992";
		"d) 1985";
	}
	(you,a){
		"Yes!!!, Here is the photobook";
		move photobook from offscreen to you;
		move you from wsMsPeepersQuiz to wsSchoolOutside;
	}
	(you,b){
		"Wrong, See ya!";
		move you from wsMsPeepersQuiz to wsSchoolOutside;
	}
	(you,c){
		"Wrong, See ya!";
		move you from wsMsPeepersQuiz to wsSchoolOutside;
	}
	(you,d){
		"Wrong, See ya!";
		move you from wsMsPeepersQuiz to wsSchoolOutside;
	}
}

room wsTownHallOutside{
	enter{
		"You arrive in front of the town hall";
	}
	(you,look){
		"The town hall is not very impressive.";
		"It appears to be open for business. (North)";
	}
	(you,n){
		move you from wsTownHallOutside to wsTownHallInside;
	}
	(you,s){
		move you from wsTownHallOutside to westshanbar;
	}
}

room wsTownHallInside{
	enter{
		"You are now inside the town hall.";
	}
	(you,look){
		"The mayor is working behind a desk.";
		"You can leave (s)";
	}
	(you,talk){
		"The mayor says: Good day, sir";
	}
	(you,s){
		move you from wsTownHallInside to wsTownHallOutside;
	}
}

room wsFacingRiver{
	enter{
		"You are now facing the river, looking at the old bridge";
	}
	(you,look){
		"You can go under the bridge (West)";
		"You can go in the water for a swim (North)";
		"You can turn around (South)";
		"You can go to the Old Mill (East)";
	}
	(you,n){
		"You jump off the bridge";
		"As you land, you remember you can't swim";
		+game.lose;
	}
	(you,s){
		move you from wsFacingRiver to westshanbar;
	}
	(you,e){
		move you from wsFacingRiver to wsOldMillOutside;
	}
	(you,w){
		move you from wsFacingRiver to wsUnderBridge;
	}
}

room wsOldMillOutside{
	enter{
		"You are in front of the old Mill";
		if(you.shotsHad == 3){
			"You feel a little bit dizzy, those 3 shots of rye were too much";
			you.shotsHad = 0;
		}
	}
	(you,look){
		"You see the entrance to the mill (North)";
		"You can go back to the old bridge (South)";
	}
	(you,s){
		move you from wsOldMillOutside to wsFacingRiver;
	}
	(you,n){
		move you from wsOldMillOutside to wsOldMillInside;
	}
}

room wsOldMillInside{
	counter{boosShotsHad 0 4}
	enter{
		"You see a big guy sitting on a chair";
		"Boos Myller: Hello there!";
		"Boos Myller: Want some rye? 'Course you do!";
		"Boos hands you a shot of rye";
		" ";
		"Boos Myller: Here's to us!";
		"What will you do?";
	}
	(you,look){
		if(wsOldMillInside.boosShotsHad == 4){
			"You see Boos Myller, lying on the floor";
		}
		else{
			"You see Boos Myller sitting on his chair, smiling";
		}
		if(wsOldMillInside contains flask){
			"You see Boos' flask on the floor";
		}
	}
	(you,drink){
		"You take the shot";
		you.shotsHad++;
		wsOldMillInside.boosShotsHad++;
		if(you.shotsHad == 3){
			"After that 3rd shot you suddenly faint";
			move you from wsOldMillInside to wsOldMillOutside;
		}
		if(wsOldMillInside.boosShotsHad == 4){
			"Boos Myller faints from drinking too much";
			"He drops his flask on the floor";
			move flask from offscreen to wsOldMillInside;
		}
	}
	exit{
		//When you leave
		//Boos will wake up and pick up his flask
		if(wsOldMillInside contains flask){
			move flask from wsOldMillInside to offscreen;
		}
		wsOldMillInside.boosShotsHad = 0;
		you.shotsHad = 0;
	}
}

room wsUnderBridge{
	enter{
		"You are now under the old bridge";
	}
}

(you,drop,stuff $s) {
	places $p;
	if (you contains $s && $p contains you) {
		move $s from you to $p;
		"You drop the ${s}.";
	} else {
		"You don't have the ${s}.";
	}
}

(you,take,stuff $s) {
	places $p;
	if ($p contains $s && $p contains you) {
		move $s from $p to you;
		"You pick up the ${s}.";
	} else {
		"There is no ${s} here.";
	}
}

(you,quit) {
	"Good bye";
	+game.lose;
}

start {
	"                 -= Return to =-";
	"*********     *******     ********     ***   ***";
	"*********    *********    *********    ***  ***";
	"      ***    ***   ***    ***   ***    *** ***";
	"     ***     ***   ***    ***   ***    ******";
	"    ***      ***   ***    *********    *****";
	"   ***       ***   ***    ********     *****";
	"  ***        ***   ***    *** ***      ******";
	" ***         ***   ***    ***  ***     *** ***";
	"*********    *********    ***   ***    ***  ***";
	"*********     *******     ***    ***   ***   ***";
	"Part 2";
	move you from offscreen to westshanbar;
	move knife from offscreen to you;
	move crank from offscreen to wsHardwareStoreInside;
	move mice from offscreen to wsHardwareStoreInside;
	move box from offscreen to wsHardwareStoreInside;
	-?wsMsPeepersQuiz.entered;
	"You arrive in West Shanbar";
}